Mehrere Fragen zu Overpass-Turbo Abfrage

Communities Deutschland (Germany)
1

Hallo Community,

ich tagge seit einiger Zeit vor allem das 20kV Strom-Netz hier in der Gegend. Grundsätzlich möchte ich damit einige technische Fragestellungen im Nachgang erledigen. Um mich der Thematik zu nähern möchte ich eine Abfrage mit overpass turbo durchführen, scheitere jedoch an der Syntax. Auch tagelanges googeln brachte mich nicht weiter.
Elemente einer Region abzurufen ist ja erstmal einfach. Aber dann für diese Elemente wieder übergeordnete Informationen zu erhalten, das ist mein Problem.
Beispiel:
Liste mit allen Verteil-Transformatoren einer Area:

[out:csv(_row;false)];

area[name="GVV Dreisamtal"]->.a;
make out _row = "Transformatoren " +a.set(t["name"]); out;
make out _row = "---------------------------"; out;
node(area.a)[transformer=distribution];
foreach->.trafo(
  make out _row = 
   trafo.set(t["description"])+ ", "+
   trafo.set(t["voltage:primary"]+"/"+
   trafo.set(t["voltage:secondary"])
    );
out;
);

Wie kann ich pro Trafo die Gemeinde mit auflisten?
Kann ich innerhalb der foreach Schleife mit (if: ) nochmals Elemente unterscheiden (Masttrafos / Stationen)?

Bin für jeden Tipp dankbar.
vg Wissmo

2

Fangen wir mal mit der ersten Frage an. Was ist eine Gemeinde? Passt das folgende?


area[name="GVV Dreisamtal"]->.a;
rel(area.a)[boundary=administrative](if:number(t[admin_level])>8);
out geom;

Dann sieht die Query mit Gemeinde so aus:


[out:csv(_row;false)];

area[name="GVV Dreisamtal"]->.a;
rel(area.a)[boundary=administrative](if:number(t[admin_level])>8);
map_to_area->.gemeinden;

make out _row = "Transformatoren " +a.u(t["name"]); out;
make out _row = "---------------------------"; out;
node(area.a)[transformer=distribution]->.trafos;

foreach.gemeinden -> .gemeinde(
  node.trafos(area.gemeinde);
  foreach->.trafo(
    make out _row = 
     gemeinde.u(t[name]) + ": " + 
     trafo.u(t["description"])+ ", "+
     trafo.u(t["voltage:primary"])+"/"+
     trafo.u(t["voltage:secondary"]);
    out;
  );
);
3

Das sieht doch schon mal gut aus.
Damit kann ich weiterarbeiten. Vielen Dank.

Die zweite Frage kann ich mit Ausgabe von ‘power’ (pole oder transformer) umschiffen.

Wie kann ich eigentlich einen Way (=Leitung / power=minor_line) auflisten, der an einem Node (Trafo) angeschlossen ist?
Am liebsten würde ich das in der gleichen Abfrage mit auflisten.