Limiting a complex query to an area

ChillyDL · 2022-12-19T14:38:42.407Z

Hello, I am trying to limit a query to, say, Germany:

[out:json];
{{geocodeArea:Deutschland}};
// Find objects tagged "megalith" using the tag "site_type" OR "archaeological_site"
(
  nwr["site_type"="megalith"](area);
  nwr["archaeological_site"="megalith"](area);
);
out body;
>;
out skel qt;

This query though seems to ignore the second line in the union statement, nwr["archaeological_site"="megalith"](area);
Same if I flip the first and second line.

What is going on? And how can I achieve this?

mmd · 2022-12-19T14:52:03.206Z

Check out the following questions:

geolocation - Why does 'around' work but 'area' doesn't in Overpass Turbo? - Stack Overflow
javascript - Location query in Overpass turbo - Stack Overflow

mcliquid · 2022-12-19T15:32:38.617Z

I’ve just used the Wizard to create this query and it seems to work:

/*
This has been generated by the overpass-turbo wizard.
The original search was:
“archaeological_site=megalith or site_type=megalith in Deutschland”
*/
[out:json][timeout:2500];
// fetch area “Deutschland” to search in
{{geocodeArea:Deutschland}}->.searchArea;
// gather results
(
  // query part for: “archaeological_site=megalith”
  node["archaeological_site"="megalith"](area.searchArea);
  way["archaeological_site"="megalith"](area.searchArea);
  relation["archaeological_site"="megalith"](area.searchArea);
  // query part for: “site_type=megalith”
  node["site_type"="megalith"](area.searchArea);
  way["site_type"="megalith"](area.searchArea);
  relation["site_type"="megalith"](area.searchArea);
);
// print results
out body;
>;
out skel qt;

Link: overpass turbo

image454×595 196 KB

ChillyDL · 2022-12-20T09:20:46.515Z

Thanks! So, in a nutshell:
In Overpass Turbo, the area needs to be stored in a named inputset. Otherwise, the result of the first statement will overwrite the area in the default inputset ._, and will no longer be available for the next query, I learn.

So, this works:

[out:json];
{{geocodeArea:Deutschland}}->.searchArea;
(
  nwr["site_type"="megalith"](area.searchArea);
  nwr["archaeological_site"="megalith"](area.searchArea);
);
out body;
>;
out skel qt;